Utilizzo delle date di SQL Server

L'utilizzo delle date in SQL Server può essere frustrante e richiedere molto tempo. Condividiamo alcune delle nostre funzioni più portatili utilizzando una tabella di calendario per archiviare e calcolare festività e fine settimana, nonché impostare frequenze ricorrenti.

Di

La maggior parte del lavoro che abbiamo intrapreso in precedenza ha comportato il lavoro con date, età e varie altre informazioni. Cose come calcolare l'età non sono così semplici come potrebbero essere. Abbiamo già scritto una selezione di articoli in precedenza, ma ora vengono sostituiti da un paio di funzioni più flessibili per ridurre il numero di funzioni necessarie.

In questo articolo andremo a configurare la nostra tabella dei calendari riutilizzabile e il tavolo delle festività bancarie, per poi popolarlo. Varie funzioni saranno scritte come articoli separati in cui è possibile ottenere ulteriori informazioni.

Tendiamo a utilizzare un database "Utility" condiviso con tutte le nostre funzioni al suo interno per ridurre le esigenze di controllo delle modifiche e dati coerenti.

Crea Database

Se hai un database condiviso, o sai dove vuoi archiviarlo, allora queste funzioni sono libere, tuttavia tutto il codice da qui è stato progettato per essere eseguito in un singolo script in SQL Server 2016.

Nota! - Potrebbe essere più facile creare il tuo database in SSMS

Mancia! - Impostare le opzioni in modo semplice per evitare che il file di registro aumenti e che i dati abbiano meno probabilità di essere critici per l'azienda.

SQL

CREATE DATABASE [Utilities]
    CONTAINMENT = NONE ONPRIMARY (
    NAME = N'Utilities',FILENAME = N'C:\Program Files\Microsoft SQL Server\MSSQL13.SQLSERVER13\MSSQL\DATA\Utilities.mdf' , SIZE = 8192KB , FILEGROWTH = 65536KB)
    LOG ON (
    NAME = N'Utilities_log',FILENAME = N'C:\Program Files\Microsoft SQL Server\MSSQL13.SQLSERVER13\MSSQL\DATA\Utilities_log.ldf' , SIZE = 8192KB , FILEGROWTH = 65536KB)
GO

Crea schema

Per semplificare la gestione, abbiamo creato uno schema chiamato Date e archiviamo tutte le nostre informazioni correlate in questo. Pensa allo schema in questo senso come contenitore o spazio dei nomi per gli oggetti correlati.

Mancia! - Quando si crea uno schema in istruzioni SQL batch, inserirlo in un'istruzione sp_executesql per evitare che il sistema si lamenti che sia l'unica istruzione nel batch. Se può esistere, avvolgilo in un blocco try per consentire il passaggio del codice.

SQL

USE Utilities
GO
SET NOCOUNT ON;
BEGIN TRY
EXEC sp_executesql N'CREATE SCHEMA Dates'
END TRY BEGIN CATCH END CATCH;
GO
BEGIN TRY
EXEC sp_executesql N'CREATE SCHEMA Test'
END TRY BEGIN CATCH END CATCH;
GO

Funzioni condivise

Ci sono un paio di funzioni condivise che verranno utilizzate più avanti, quindi forniremo il codice e il link, con una spiegazione su ogni pagina. Ci sono un paio di cose da notare:

I calcoli del DateDiff standard sono puramente annuali, quindi per calcolare l'età è necessario verificare se tale data è più alta o meno. La nostra funzione GetLeapYear era il modo più intelligente per capire se avevamo bisogno di aggiungere un giorno.

La data di Pasqua può fallire se non si utilizza la nuova funzione DateFromParts, a causa della mancanza di riempimento del giorno.

GetLeapYear

CREATE FUNCTION Dates.GetLeapYear(@Date DATETIME2) RETURNS BIT AS BEGIN
DECLARE @Ret BIT=(CASE WHEN DATEPART(YEAR,@Date)%4<>0 OR (DATEPART(YEAR,@Date)%100=0 AND DATEPART(YEAR,@Date)%400<>0) THEN 0 ELSE 1 END)
RETURN @Ret
END
GO

ancora: Ottieni l'anno bisestile

GetAge

CREATE FUNCTION Dates.GetAge(@Date DATETIME2,@Until DATETIME2) RETURNS INT AS BEGIN
IF @Until IS NULL SET @Until=CONVERT(DATE,GETDATE())
DECLARE @Age INT=DATEDIFF(YEAR,@Date,@Until)
+(CASE WHEN DATEPART(DAYOFYEAR,@Date)>
(DATEPART(DAYOFYEAR,@Until)+(CASE WHEN dbo.GetLeapYear(@Date)=1 AND DATEPART(DAYOFYEAR,@Date)>59 THEN 1 ELSE 0 END))
THEN -1 ELSE 0 END)
RETURN @Age
END
GO

ancora: Ottieni l'età

DatePad

CREATE FUNCTION Dates.DatePad(@PadValue NVARCHAR(100),@PadLen INT) RETURNS NVARCHAR(4) AS BEGIN
RETURN ISNULL(REPLICATE('0',@PadLen-LEN(@PadValue))+@PadValue,LEFT(@PadValue,@PadLen))
END
GO

ancora: Funzione di riempimento della data

DateFromParts

CREATE FUNCTION Dates.DateFromParts(@Year SMALLINT,@Month SMALLINT,@Day SMALLINT) RETURNS DATETIME2 AS BEGIN
DECLARE @Date DATETIME2=Dates.DatePad(@Year,4)+'-'+Dates.DatePad(@Month,2)+'-'+Dates.DatePad(@Day,2)
RETURN @Date
END
GO

ancora: Funzione SQL Server DATEFROMPARTS per le versioni pre 2012

GetEasterDate

CREATE FUNCTION Dates.GetEasterDate(@Year INT) RETURNS DATETIME2 AS BEGIN
/*Calculate date of easter based on Year passed - adjusted from Wikipedia*/
Declare @GregorianEaster DATETIME2
Declare @a INT, @b INT, @c INT, @d INT, @e INT, @f INT, @g INT, @h INT, @i INT, @k INT, @L INT, @m INT, @Month INT, @Day INT
SET @a = @Year % 19
SET @b = floor(@Year/ 100)
SET @c = @Year % 100
SET @d = floor(@b/ 4)

SET @e = @b % 4

SET @f = floor((@b+ 8) / 25)

SET @g = floor((@b- @f + 1)/3)

SET @h = (19*@a+ @b - @d - @g + 15) % 30

SET @i = floor(@c/ 4)

SET @k = @c % 4

SET @L = (32 + 2*@e + 2*@i- @h - @k) % 7

SET @m = floor((@a+ 11*@h + 22*@L)/ 451)

SET @month = floor((@h+ @L - 7*@m + 114) / 31)

SET @day = (@h + @L - 7*@m + 114) % 31 + 1

SET @GregorianEaster = Dates.DateFromParts(@Year,@Month,@Day)

RETURN @GregorianEaster


END

GO

Tabella delle frequenze

Per la pianificazione e la ricorrenza, usiamo la nostra tabella di pianificazione. Questo ci permette di calcolare quanto spesso deve essere ripetuto qualcosa.

Calendar Frequency

CREATE TABLE Dates.CalendarFrequency(FrequencyID NVARCHAR(2),FrequencyName NVARCHAR(100),FrequencyOrder INT)

GO

INSERT INTO Dates.CalendarFrequency

SELECT '','Once',0 UNION

SELECT '7','Weekly',1 UNION

SELECT '14','Fortnightly',2 UNION

SELECT '32','Monthly (Same Day 1st,15th,28th etc)',3  UNION

SELECT '1','Monthly (First Monday,Wednesday etc)',4 UNION

SELECT '2','Monthly (Second Monday,Wednesday etc)',5 UNION

SELECT '3','Monthly (Third Monday,Wednesday etc)',6 UNION

SELECT '4','Monthly (Fourth Monday,Wednesday etc)',10 UNION

SELECT '-1','Monthly (Last Monday,Wednesday etc)',7 UNION

SELECT '-2','Monthly (Second Last Monday,Wednesday etc)',8 UNION

SELECT '-3','Monthly (Third Last Monday,Wednesday etc)',9 UNION

SELECT '-4','Monthly (Fourth Last Monday,Wednesday etc)',11

ORDER BY 3

GO

Tabella del calendario

La nostra tabella di calendario è impostata per essere eseguita per qualsiasi periodo di tempo nell'intervallo DATETIME2. In generale, il codice seguente ti fornirà un intervallo che coprirebbe la maggior parte degli scenari.

CalendarCA e CalendarCD sono i numeri delle settimane in ordine crescente e decrescente per ciascun mese e utilizzati in un riferimento incrociato rispetto alla nostra tabella delle frequenze sopra riportata.

Create Calendar Table

CREATE TABLE Dates.Calendar(

CalendarDate DATETIME2 NOT NULL CONSTRAINT PK_CalendarDate PRIMARY KEY,

CalendarCA AS (DATEDIFF(DAY,DATEADD(DAY,1-DATEPART(DAY,CalendarDate),CalendarDate),CalendarDate)/7)+1 PERSISTED,

CalendarCD AS (DATEDIFF(DAY,CalendarDate,DATEADD(DAY,-1,DATEADD(MONTH,1,DATEADD(DAY,1-DATEPART(DAY,CalendarDate),CalendarDate))))/7)+1 PERSISTED,

WeekDayID AS (DATEPART(weekday,[CalendarDate])),

WeekDayName AS (case DATEPART(weekday,[CalendarDate]) when (1) then 'Sunday' when (2) then 'Monday' when (3) then 'Tuesday' when (4) then 'Wednesday' when (5) then 'Thursday' when (6) then 'Friday' when (7) then 'Saturday'  end))

GO

DECLARE @D DATETIME2='1850-01-01'

WHILE @D<='2099-12-31' BEGIN

INSERT INTO Dates.Calendar(CalendarDate) SELECT @D

SET @D=DATEADD(DAY,1,@D)

END

GO

Tabella delle feste

Abbiamo progettato la tabella delle festività per essere il più flessibile possibile e consentire l'archiviazione di diverse opzioni aggiungendo la colonna Funzione calendario. Di seguito abbiamo archiviato separatamente le festività per Inghilterra e Galles, Scozia e Irlanda del Nord, facendo riferimento incrociato alla tabella del calendario già creata.

In teoria puoi avere tutti gli schemi che vuoi.

Create Holidays Table


CREATE TABLE Dates.CalendarHolidays(CalendarDate DATETIME2 NOT NULL,CalendarFunction INT NOT NULL,HolidayType VARCHAR(100) NULL,CONSTRAINT PK_Holidays_Id PRIMARY KEY(CalendarDate,CalendarFunction))

GO

/*English & Welsh Holidays*/

INSERT INTO Dates.CalendarHolidays

SELECT CalendarDate,0,'New Years Day' FROM Dates.Calendar WHERE DATEPART(MONTH,CalendarDate)=1 AND DATEPART(DAY,CalendarDate)=1 UNION --New Years Day

SELECT CalendarDate,0,'Good Friday' FROM Dates.Calendar WHERE CalendarDate=DATEADD(DAY,-2,Dates.GetEasterDate(DATEPART(YEAR,CalendarDate))) UNION--Good Friday

SELECT CalendarDate,0,'Easter Monday' FROM Dates.Calendar WHERE CalendarDate=DATEADD(DAY,1,Dates.GetEasterDate(DATEPART(YEAR,CalendarDate))) UNION--Easter Monday

SELECT CalendarDate,0,'May Holidays' FROM Dates.Calendar WHERE DATEPART(MONTH,CalendarDate)=5 AND WeekDayID=2 AND (CalendarCA=1 OR CalendarCD=1)UNION--May Holidays

SELECT CalendarDate,0,'August Holidays' FROM Dates.Calendar WHERE DATEPART(MONTH,CalendarDate)=8 AND WeekDayID=2 AND (CalendarCD=1) UNION--August Holidays

SELECT CalendarDate,0,'Christmas Day' FROM Dates.Calendar WHERE DATEPART(MONTH,CalendarDate)=12 AND DATEPART(DAY,CalendarDate)=25 UNION --Christmas Day

SELECT CalendarDate,0,'Boxing Day' FROM Dates.Calendar WHERE DATEPART(MONTH,CalendarDate)=12 AND DATEPART(DAY,CalendarDate)=26 --Boxing Day

GO

/*Scotish  Holidays*/

INSERT INTO Dates.CalendarHolidays

SELECT CalendarDate,1,'New Years Day' FROM Dates.Calendar WHERE DATEPART(MONTH,CalendarDate)=1AND DATEPART(DAY,CalendarDate)=1 UNION --New Years Day

SELECT CalendarDate,1,'2nd' FROM Dates.Calendar WHERE DATEPART(MONTH,CalendarDate)=1 AND DATEPART(DAY,CalendarDate)=2 UNION --New Years Day

SELECT CalendarDate,1,'Good Friday' FROM Dates.Calendar WHERE CalendarDate=DATEADD(DAY,-2,Dates.GetEasterDate(DATEPART(YEAR,CalendarDate)))UNION--Good Friday

SELECT CalendarDate,1,'May Holidays' FROM Dates.Calendar WHERE DATEPART(MONTH,CalendarDate)=5 AND WeekDayID=2 AND (CalendarCA=1 OR CalendarCD=1)UNION--May Holidays

SELECT CalendarDate,1,'August Holidays' FROM Dates.Calendar WHERE DATEPART(MONTH,CalendarDate)=8 AND WeekDayID=2 AND (CalendarCA=1) UNION--August Holidays

SELECT CalendarDate,1,'St Andrews' FROM Dates.Calendar WHERE DATEPART(MONTH,CalendarDate)=11 AND DATEPART(DAY,CalendarDate)=30 UNION --St Andrews

SELECT CalendarDate,1,'Christmas Day' FROM Dates.Calendar WHERE DATEPART(MONTH,CalendarDate)=12 AND DATEPART(DAY,CalendarDate)=25 UNION --Christmas Day

SELECT CalendarDate,1,'Boxing Day' FROM Dates.Calendar WHERE DATEPART(MONTH,CalendarDate)=12 AND DATEPART(DAY,CalendarDate)=26 --Boxing Day

GO

/*Northern Irish Holidays*/

INSERT INTO Dates.CalendarHolidays

SELECT CalendarDate,2,'New Years Day' FROM Dates.Calendar WHERE DATEPART(MONTH,CalendarDate)=1 AND DATEPART(DAY,CalendarDate)=1 UNION --New Years Day

SELECT CalendarDate,2,'Good Friday' FROM Dates.Calendar WHERE CalendarDate=DATEADD(DAY,-2,Dates.GetEasterDate(DATEPART(YEAR,CalendarDate))) UNION--Good Friday

SELECT CalendarDate,2,'Easter Monday' FROM Dates.Calendar WHERE CalendarDate=DATEADD(DAY,1,Dates.GetEasterDate(DATEPART(YEAR,CalendarDate))) UNION--Easter Monday

SELECT CalendarDate,2,'May Holidays' FROM Dates.Calendar WHERE DATEPART(MONTH,CalendarDate)=5 AND WeekDayID=2 AND (CalendarCA=1 OR CalendarCD=1)UNION--May Holidays

SELECT CalendarDate,2,'Battle of the Boyne' FROM Dates.Calendar WHERE DATEPART(MONTH,CalendarDate)=7 AND DATEPART(DAY,CalendarDate)=12 UNION --Battle of the Boyne

SELECT CalendarDate,2,'August Holidays' FROM Dates.Calendar WHERE DATEPART(MONTH,CalendarDate)=8 AND WeekDayID=2 AND (CalendarCA=1) UNION--August Holidays

SELECT CalendarDate,2,'Christmas Day' FROM Dates.Calendar WHERE DATEPART(MONTH,CalendarDate)=12 AND DATEPART(DAY,CalendarDate)=25 UNION --Christmas Day

SELECT CalendarDate,2,'Boxing Day' FROM Dates.Calendar WHERE DATEPART(MONTH,CalendarDate)=12 AND DATEPART(DAY,CalendarDate)=26 --Boxing Day
GO

Bit intelligenti

Ci sono tre funzioni utilizzate che le combinano in vari modi, tutte con opzioni molto simili.

GetDateAdjusted sposta la data in avanti o all'indietro di un determinato numero di giorni, in base alla funzione del calendario, e se si desidera includere festività o fine settimana.
GetDaysAdjusted conta il numero di giorni tra due date, a seconda della funzione del calendario, e se si desidera includere le festività eo i fine settimana. Le date possono essere contate in modo inclusivo o esclusivo.
GetMonthAdjusted conta il numero di giorni in un mese, a seconda della funzione del calendario e se si desidera includere le festività eo i fine settimana. Le date possono essere contate in modo inclusivo o esclusivo.

GetDateAdjusted

CREATE FUNCTION Dates.GetDateAdjusted(@AdjustDate AS DATETIME2,@CalendarFunction INT,@AdjustDays AS INT,@AdjustMode BIT,@AdjustWeekEnds BIT,@AdjustHolidays BIT) RETURNS DATETIME2 AS BEGIN

SELECT @AdjustDate=DATEADD(DAY,(CASE @AdjustMode WHEN 0 THEN -1 ELSE 1 END),@AdjustDate),

              @AdjustDays=(CASE @AdjustMode WHEN 0 THEN @AdjustDays+1 ELSE (0-@AdjustDays)-1 END)

DECLARE @AdjustCount INT=0,@AdjustWorkDays INT=0,@Date DATETIME2=@AdjustDate

/*Forwards*/

WHILE @AdjustMode=0 AND @AdjustWorkDays < @AdjustDays

BEGIN

       SET @AdjustCount=@AdjustCount+1

       SET @Date=DATEADD(DAY,@AdjustCount,@AdjustDate)

       IF NOT ((DATEPART(WEEKDAY,@Date) IN (1,7) AND @AdjustWeekEnds=1)

              OR

              EXISTS (SELECT * FROM Dates.CalendarHolidays WHERE CalendarDate=@Date AND CalendarFunction=@CalendarFunction AND @AdjustHolidays=1))

       BEGIN

              SET @AdjustWorkDays = @AdjustWorkDays + 1

       END

END

/*Backwards*/

WHILE @AdjustMode=1 AND @AdjustWorkDays > @AdjustDays

BEGIN

       SET @AdjustCount=@AdjustCount-1            

       SET @Date=DATEADD(DAY,@AdjustCount,@AdjustDate)

       IF NOT ((DATEPART(WEEKDAY,@Date) IN (1,7)AND @AdjustWeekEnds=1)

              OR

              EXISTS (SELECT * FROM Dates.CalendarHolidays WHERE CalendarDate=@Date AND CalendarFunction=@CalendarFunction AND @AdjustHolidays=1))

       BEGIN

              SET @AdjustWorkDays = @AdjustWorkDays - 1

       END

END            

RETURN @Date            

END            

GO

ancora: Date - Aggiunta di giorni lavorativi a una data esclusa la festività

GetDaysAdjusted

CREATE FUNCTION Dates.GetDaysAdjusted(@DateFrom As DATETIME2,@CalendarFunction INT,@DateTo AS DATETIME2,@AdjustMode BIT,@AdjustWeekEnds BIT,@AdjustHolidays BIT) RETURNS INT AS BEGIN

/*@AdjustMode 0=Count whole days only,1=Any day counts as 1*/

IF @DateFrom>@DateTo BEGIN

       DECLARE @T DATETIME2=@DateTo,@F DATETIME2=@DateFrom

       SELECT @DateFrom=@T,@DateTo=@F

END

DECLARE @Count AS INT=0,@Date As DATETIME2=@DateFrom

WHILE @Date < @DateTo BEGIN

IF ((DATEPART(WEEKDAY,@Date) IN (1,7) AND @AdjustWeekEnds=1)

       OR

       EXISTS (SELECT * FROM Dates.CalendarHolidays WHERE CalendarDate=@Date AND CalendarFunction=@CalendarFunction AND @AdjustHolidays=1))

              BEGIN

              SELECT @Count = @Count + 1

              END

SELECT @Date=DATEADD(DAY,1,@Date)

END

RETURN (DATEDIFF(DAY,@DateFrom,@DateTo)-(@Count))+@AdjustMode

END

GO

ancora: Calcolo dei giorni lavorativi tra due date escluse le festività in SQL Server

GetMonthAdjusted

CREATE FUNCTION Dates.GetMonthAdjusted(@Month As DATETIME2,@CalendarFunction INT,@AdjustMode BIT,@AdjustWeekEnds BIT,@AdjustHolidays BIT)

RETURNS INT AS BEGIN

DECLARE @StartDate DATETIME2=CONVERT(DATE,DATEADD(DAY,1-DAY(@Month),@Month))

DECLARE @EndDate DATETIME2=DATEADD(DAY,-1,DATEADD(MONTH,1,@StartDate)),@Count AS INT=0,@Date As DATETIME2=@StartDate

WHILE @Date < @EndDate

BEGIN

IF ((DATEPART(WEEKDAY,@Date) IN(1,7) AND @AdjustWeekEnds=1)

       OR

       EXISTS (SELECT * FROM Dates.CalendarHolidays WHERE CalendarDate=@Date AND CalendarFunction=@CalendarFunction AND @AdjustHolidays=1))

       BEGIN

       SELECT @Count = @Count + 1

       END

SET @Date=DATEADD(DAY, 1,@Date)

END

RETURN (DATEDIFF(DAY,@StartDate,@EndDate)-(@Count))+@AdjustMode

END

ancora: Date - Calcolo dei giorni lavorativi in un mese escluse le festività

Unire i dati

Mentre puoi aggiungere un join alla tua istruzione select, abbiamo trovato più facile fare riferimento in un'altra funzione. Aggiungendo due date, la frequenza e il numero della settimana mensile crescente e discendente, è possibile verificare le date pertinenti per una corrispondenza.

DateJoin Function


CREATE FUNCTION Dates.DateJoin(@CalendarDate DATETIME,@CrossoverDate DATETIME,@Frequency INT,@WeekAsc INT,@WeekDesc INT) RETURNS BIT AS BEGIN

DECLARE @J BIT=0

/*Once*/

IF @CrossoverDate=@CalendarDate SET @J=1

/*Weekly/Fornightly*/

IF @J=0 AND @Frequency IN (7,14) BEGIN

IF DATEPART(WEEKDAY,@CrossoverDate)=DATEPART(WEEKDAY,@CalendarDate) AND DATEDIFF(DAY,@CrossoverDate,@CalendarDate)%@Frequency=0

SET @J=1

END

/*Monthly*/

IF @J=0 AND @Frequency IN (32) BEGIN

IF (DATEPART(DAY,@CalendarDate)=DATEPART(DAY,@CrossoverDate)

) OR (

DATEPART(MONTH,DATEADD(DAY,1,@CalendarDate))<>

DATEPART(MONTH,@CalendarDate)

AND

DATEPART(MONTH,DATEADD(DAY,1,DATEADD(MONTH,DATEDIFF(MONTH,@CrossoverDate,@CalendarDate),@CrossoverDate)))<>

DATEPART(MONTH,DATEADD(MONTH,DATEDIFF(MONTH,@CrossoverDate,@CalendarDate),@CrossoverDate)))

SET @J=1

END

/*First/Second/Third/Fourth*/

IF @J=0 AND @Frequency IN (1,2,3,4)IF (DATEPART(WEEKDAY,@CrossoverDate)=DATEPART(WEEKDAY,@CalendarDate) AND @WeekAsc=@Frequency) SET @J=1

/*First/Second/Third/Fourth Last*/

IF @J=0 AND @Frequency IN (-1,-2,-3,-4)
IF (DATEPART(WEEKDAY,@CrossoverDate)=DATEPART(WEEKDAY,@CalendarDate) AND @WeekDesc=(-@Frequency)) SET @J=1

RETURN @J

END

GO

Data del test

Ora possiamo testare questi dati generando una tabella di pianificazione falsa.

Nel nostro esempio, la creazione di un rapporto è prevista per il primo gennaio 2017 e si ripete ogni mese il primo con tutte le possibili azioni disponibili.

Considerando l'01/01/2018 in isolamento, il comportamento nei fine settimana e nei giorni festivi potrebbe cambiare l'intervallo di date in qualsiasi data, dal 29/12/2017 al 02/01/2018.

Test Data Script


CREATE TABLE Test.Schedule(

ReportID INT,

ReportName NVARCHAR(100),

ReportStartDate DATETIME2,

ReportFrequency INT,

ReportAdjustBehaviour BIT,

ReportAdjustWeekend BIT,

ReportAdjustHoliday BIT,

ProducedBy NVARCHAR(100))

GO

INSERT INTO Test.Schedule SELECT 1,'Schedule Before - Weekends=0,Holidays=0','2017-01-01',32,1,0,0,''

INSERT INTO Test.Schedule SELECT 1,'Schedule Before - Weekends=1,Holidays=0','2017-01-01',32,1,1,0,''

INSERT INTO Test.Schedule SELECT 1,'Schedule Before - Weekends=0,Holidays=1','2017-01-01',32,1,0,1,''

INSERT INTO Test.Schedule SELECT 1,'Schedule Before - Weekends=1,Holidays=1','2017-01-01',32,1,1,1,''

INSERT INTO Test.Schedule SELECT 1,'Schedule After - Weekends=0,Holidays=0','2017-01-01',32,0,0,0,''

INSERT INTO Test.Schedule SELECT 1,'Schedule After - Weekends=1,Holidays=0','2017-01-01',32,0,1,0,''

INSERT INTO Test.Schedule SELECT 1,'Schedule After - Weekends=0,Holidays=1','2017-01-01',32,0,0,1,''

INSERT INTO Test.Schedule SELECT 1,'Schedule After - Weekends=1,Holidays=1','2017-01-01',32,0,1,1,''

GO

SELECT (case DATEPART(weekday,DateAdjusted) when (1) then 'Sunday' when (2) then 'Monday' when (3) then 'Tuesday' when (4) then 'Wednesday' when (5) then 'Thursday' when (6) then 'Friday' when (7) then 'Saturday' end) DayAdjusted,

DateAdjusted,WeekDayName,CalendarDate,ReportName,FrequencyName

FROM (

SELECT Dates.GetDateAdjusted(CalendarDate,0,0,ReportAdjustBehaviour,ReportAdjustWeekend,ReportAdjustHoliday) DateAdjusted,c.CalendarDate,WeekDayName,s.*,f.FrequencyName

FROM (SELECT * FROM Dates.Calendar WHERE CalendarDate BETWEEN '2018-01-01' AND '2018-12-31') c

INNER JOIN Test.Schedule s ON (CalendarDate>=ReportStartDate --AND CalendarDate>GETDATE()

) AND (Dates.DateJoin(CalendarDate,ReportStartDate,ReportFrequency,CalendarCA,CalendarCD)=1)

INNER JOIN Dates.CalendarFrequency f ON f.FrequencyID=ReportFrequency

) x

ORDER BY CalendarDate,DateAdjusted,ReportName

Results

DayAdjusted DateAdjusted WeekDayName CalenderDate ReportName FrequencyName Friday 29/12/2017 Monday 01/01/2018 Schedule Before - Weekends=1,Holidays=1 Monthly (Same Day 1st,15th,28th etc) Sunday 31/12/2017 Monday 01/01/2018 Schedule Before - Weekends=0,Holidays=1 Monthly (Same Day 1st,15th,28th etc) Monday 01/01/2018 Monday 01/01/2018 Schedule After - Weekends=0,Holidays=0 Monthly (Same Day 1st,15th,28th etc) Monday 01/01/2018 Monday 01/01/2018 Schedule After - Weekends=1,Holidays=0 Monthly (Same Day 1st,15th,28th etc) Monday 01/01/2018 Monday 01/01/2018 Schedule Before - Weekends=0,Holidays=0 Monthly (Same Day 1st,15th,28th etc) Monday 01/01/2018 Monday 01/01/2018 Schedule Before - Weekends=1,Holidays=0 Monthly (Same Day 1st,15th,28th etc) Tuesday 02/01/2018 Monday 01/01/2018 Schedule After - Weekends=0,Holidays=1 Monthly (Same Day 1st,15th,28th etc) Tuesday 02/01/2018 Monday 01/01/2018 Schedule After - Weekends=1,Holidays=1 Monthly (Same Day 1st,15th,28th etc)

DayAdjusted	DateAdjusted	WeekDayName	CalenderDate	ReportName	FrequencyName
Friday	29/12/2017	Monday	01/01/2018	Schedule Before - Weekends=1,Holidays=1	Monthly (Same Day 1st,15th,28th etc)
Sunday	31/12/2017	Monday	01/01/2018	Schedule Before - Weekends=0,Holidays=1	Monthly (Same Day 1st,15th,28th etc)
Monday	01/01/2018	Monday	01/01/2018	Schedule After - Weekends=0,Holidays=0	Monthly (Same Day 1st,15th,28th etc)
Monday	01/01/2018	Monday	01/01/2018	Schedule After - Weekends=1,Holidays=0	Monthly (Same Day 1st,15th,28th etc)
Monday	01/01/2018	Monday	01/01/2018	Schedule Before - Weekends=0,Holidays=0	Monthly (Same Day 1st,15th,28th etc)
Monday	01/01/2018	Monday	01/01/2018	Schedule Before - Weekends=1,Holidays=0	Monthly (Same Day 1st,15th,28th etc)
Tuesday	02/01/2018	Monday	01/01/2018	Schedule After - Weekends=0,Holidays=1	Monthly (Same Day 1st,15th,28th etc)
Tuesday	02/01/2018	Monday	01/01/2018	Schedule After - Weekends=1,Holidays=1	Monthly (Same Day 1st,15th,28th etc)